######################
#
#    Copyright (C) 2010 - 2012 EngSaS - Engineering Solutions and Services Langenbach. All rights reserved.
#
#    This library is free software; you can redistribute it and/or
#    modify it under the terms of the GNU Lesser General Public
#    License as published by the Free Software Foundation; either
#    version 2.1 of the License, or (at your option) any later version.
#
#    This library is distributed in the hope that it will be useful,
#    but WITHOUT ANY WARRANTY; without even the implied warranty of
#    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
#    Lesser General Public License for more details.
#
#    You should have received a copy of the GNU Lesser General Public
#    License along with this library; if not, write to the Free Software
#    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
#    MA 02110-1301  USA.
#
######################

CMAKE_MINIMUM_REQUIRED(VERSION 2.8.3)

SET(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)

PROJECT(libengsas)

SET(TARGET_VERSION_MAJOR 0 )
SET(TARGET_VERSION_MINOR 5 )
SET(${PROJECT_NAME}_PATCH_LEVEL 3 )
SET(${PROJECT_NAME}_VERSION
    "${TARGET_VERSION_MAJOR}.${TARGET_VERSION_MINOR}.${${PROJECT_NAME}_PATCH_LEVEL}" )
SET(VERSION ${${PROJECT_NAME}_VERSION})
SET(CMAKE_DEBUG_POSTFIX "d")

INCLUDE(CTest)
# Set timeout for each test (for manual mode)
# To set it with scripts see experimental.ctest
#SET(DART_TESTING_TIMEOUT 60 CACHE STRING "")

OPTION(BUILD_PACKAGE "Used to setup all stuff for packaging. To include the header files and libengsas-testing, set BUILD_DEV=ON" OFF)
OPTION(BUILD_DEV "All stuff needed for developing (e.g. QtDesigner Plugins, header, ...). Also install libengsas-testing if BUILD_PACKAGE is set to ON" ON)
OPTION(BUILD_DEBUG "Build in debug mode" OFF)
OPTION(BINDINGS_KDE "Build with KDE features" ON)
OPTION(COMPATIBLE_WITH_NON_KDE "Install KDE version compatible to non KDE version" OFF)
OPTION(L10N_ALL "Build with all languages" ON)
OPTION(L10N_DE 	"Build with german language" OFF)
OPTION(L10N_EN 	"Build with english language" OFF)
OPTION(L10N_FR 	"Build with french language" OFF)
OPTION(WITH_FILE_SERVICE_PLUGINS_ALL "Build with all EFileService plugins" ON)
OPTION(WITH_FILE_SERVICE_FILESYSTEM "Build with EFileService plugin EFileSystem which uses local file system" OFF)
OPTION(WITH_CHARTS "Build library with widgets to display charts" ON)
OPTION(WITH_API_DOCS "Generate API documentation" OFF)
OPTION(WITH_EXAMPLES "Compile examples" OFF) 

SET(BUILD_DEBUG_WANTED ${BUILD_DEBUG})
SET(BUILD_DEV_WANTED ${BUILD_DEV})
SET(BUILD_TESTING_WANTED ${BUILD_TESTING})
SET(BUILD_PACKAGE_WANTED ${BUILD_PACKAGE})
SET(BINDINGS_KDE_WANTED ${BINDINGS_KDE})
SET(COMPATIBLE_WITH_NON_KDE_WANTED ${COMPATIBLE_WITH_NON_KDE})
SET(L10N_ALL_WANTED ${L10N_ALL})
SET(L10N_DE_WANTED ${L10N_DE})
SET(L10N_EN_WANTED ${L10N_EN})
SET(L10N_FR_WANTED ${L10N_FR})
SET(WITH_FILE_SERVICE_PLUGINS_ALL_WANTED ${WITH_FILE_SERVICE_PLUGINS_ALL})
SET(WITH_FILE_SERVICE_FILESYSTEM_WANTED ${WITH_FILE_SERVICE_FILESYSTEM})
SET(WITH_CHARTS_WANTED ${WITH_CHARTS})
SET(WITH_API_DOCS_WANTED ${WITH_API_DOCS})
SET(WITH_EXAMPLES_WANTED ${WITH_EXAMPLES}) 

MARK_AS_ADVANCED(COMPATIBLE_WITH_NON_KDE WITH_API_DOCS)

# disable debug mode, when building package
IF(BUILD_PACKAGE)
	IF(BUILD_DEBUG)
		MESSAGE("warning: Disabled Debug mode, because Packagemode succeed over BUILD_DEBUG")
		SET(BUILD_DEBUG OFF)
	ENDIF(BUILD_DEBUG)
	IF(BUILD_DEV)
		SET(WITH_API_DOCS ON)
	ENDIF(BUILD_DEV)
ENDIF(BUILD_PACKAGE)

IF(BUILD_DEBUG)
	SET(CMAKE_BUILD_TYPE Debug)
ELSE(BUILD_DEBUG)
	SET(CMAKE_BUILD_TYPE Release)
ENDIF(BUILD_DEBUG)
# Qt4 must be included after setting the build type
FIND_PACKAGE(Qt4 REQUIRED)

#SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wconversion-null -Wunused-but-set-variable -Wsequence-point")
#SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wconversion-null -Wunused-but-set-variable -Wsequence-point")

SET(KDE 0)
IF(BINDINGS_KDE)
	FIND_PACKAGE(KDE4)
	IF(KDE4_FOUND)
		SET(KDE 1)
		# use, i.e. don't skip the full RPATH for the build tree
		SET(CMAKE_SKIP_BUILD_RPATH  FALSE)
		# when building, don't use the install RPATH already
		# (but later on when installing)
		SET(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
		# the RPATH to be used when installing
		SET(CMAKE_INSTALL_RPATH "")
		# don't add the automatically determined parts of the RPATH
		# which point to directories outside the build tree to the install RPATH
		# (This is the only option which is changed in fedora in FindKDE4Internal.cmake to achieve
		# the wanted behaviour)
		SET(CMAKE_INSTALL_RPATH_USE_LINK_PATH FALSE)
		ADD_DEFINITIONS(${KDE4_DEFINITIONS})
		INCLUDE(KDE4Defaults)
		INCLUDE(MacroLibrary)
		# KDE also sets BUILD_TESTING to true
		# so we set it back to chosen state
		SET(BUILD_TESTING ${BUILD_TESTING_WANTED})
	ELSE(KDE4_FOUND)
		MESSAGE("warning: KDE not found --> Disabled KDE-Bindings")
		SET(BINDINGS_KDE OFF)
		SET(KDE 0)
	ENDIF(KDE4_FOUND)
ELSE(BINDINGS_KDE)
	SET(COMPATIBLE_WITH_NON_KDE OFF)
ENDIF(BINDINGS_KDE)

IF(NOT KDE)
	IF(NOT APPLE)
		SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--no-undefined")
	ENDIF(NOT APPLE)
	IF(MSVC)
		SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DQT_NO_EXCEPTIONS")
	ELSE(MSVC)
		SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wnon-virtual-dtor -Wno-long-long -Wundef -Wcast-align -Wchar-subscripts -Wall -W -Wpointer-arith -Wformat-security -fno-exceptions -DQT_NO_EXCEPTIONS -fno-check-new -fno-common")
	ENDIF(MSVC)
	IF(NOT WIN32 AND NOT APPLE)
#		SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--fatal-warnings -lc -Wl,--disable-auto-import")
		SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--fatal-warnings -lc")
		SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ansi")
	ENDIF(NOT WIN32 AND NOT APPLE)
ENDIF(NOT KDE)
IF(BUILD_DEBUG AND NOT MSVC)
	SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -fprofile-arcs -ftest-coverage")
	SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fprofile-arcs -ftest-coverage")
ENDIF(BUILD_DEBUG AND NOT MSVC)
ADD_DEFINITIONS(${QT_DEFINITIONS})

# directory to install binaries
SET(bin_DIR ${CMAKE_INSTALL_PREFIX}/bin)
IF(WIN32)
  SET(bin_DIR .)
ENDIF(WIN32)

# shared library directory ($LIB_INSTALL_DIR)
# and directory for plugins, translations, ... ($share_DIR)
IF(NOT WIN32)
	SET(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/lib/" CACHE STRING "Where to install the library files to")
ENDIF(NOT WIN32)
SET(EXECUTABLE_OUTPUT_PATH ${CMAKE_BINARY_DIR}/bin)
IF(UNIX)
	SET(ENGSAS_EPART_DIR "${LIB_INSTALL_DIR}/${PROJECT_NAME}" CACHE STRING "Where to install EParts to")
#  SET(designer_DIR "/usr/lib/qt4/plugins/designer")
	SET(LIBRARY_OUTPUT_PATH ${CMAKE_BINARY_DIR}/lib)
	SET(include_DIR ${CMAKE_INSTALL_PREFIX}/include/engsas)
	SET(find_cmake_DIR ${CMAKE_ROOT}/Modules/)
	SET(share_DIR ${CMAKE_INSTALL_PREFIX}/share/${PROJECT_NAME})
	SET(ENGSAS_FILE_SERVICE_PLUGIN_DIR "${ENGSAS_EPART_DIR}/efileservices")
	SET(man_DIR ${CMAKE_INSTALL_PREFIX}/share/man)
	SET(example_DIR ${CMAKE_INSTALL_PREFIX}/share/doc/examples) 
ELSE(UNIX)
	SET(ENGSAS_EPART_DIR ${bin_DIR})
	SET(LIB_INSTALL_DIR ${bin_DIR})
	SET(LIBRARY_OUTPUT_PATH ${EXECUTABLE_OUTPUT_PATH})
	SET(include_DIR ${bin_DIR}/include)
	IF(BUILD_PACKAGE)
		SET(find_cmake_DIR ${bin_DIR})
	ELSE(BUILD_PACKAGE)
		SET(find_cmake_DIR ${CMAKE_ROOT}/Modules/)
	ENDIF(BUILD_PACKAGE)
	SET(share_DIR ${bin_DIR})
	SET(ENGSAS_FILE_SERVICE_PLUGIN_DIR ${bin_DIR}/efileservices)
	SET(man_DIR ${bin_DIR}/man)
	SET(example_DIR ${bin_DIR}/examples) 
ENDIF(UNIX)
# directory to install language files
SET(qm_DIR ${share_DIR}/lang)
#directory to install rcc files
SET(rcc_DIR ${share_DIR}/rcc)
# directory to install dependency files
SET(depends_DIR ${share_DIR}/depends)
SET(apidocs_DIR ${share_DIR}/apidocs)
SET(pkgconfig_DIR ${LIB_INSTALL_DIR}/pkgconfig/)

IF(COMPATIBLE_WITH_NON_KDE)
	# change the directories to avoid conflicts with non kde version
	SET(LIB_INSTALL_DIR ${LIB_INSTALL_DIR}/kde)
	# disable all shared stuff between non kde and kde version
	SET(BUILD_TESTING OFF)
	SET(BUILD_WITH_CHARTS OFF)
	SET(BUILD_DEV OFF)
	SET(L10N_ALL OFF)
	SET(WITH_FILE_SERVICE_PLUGINS_ALL OFF)
	SET(WITH_CHARTS OFF)
	SET(WITH_API_DOCS OFF)
ENDIF(COMPATIBLE_WITH_NON_KDE)

######################
#
# internatalization
#
######################
IF(L10N_ALL)
	SET(L10N_DE ON)
	SET(L10N_EN ON)
	SET(L10N_FR ON)
ENDIF(L10N_ALL)

######################
#
# EFileServicePlugins
#
######################
IF(WITH_FILE_SERVICE_PLUGINS_ALL)
	SET(WITH_FILE_SERVICE_FILESYSTEM ON)
ENDIF(WITH_FILE_SERVICE_PLUGINS_ALL)

CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/CTestCustom.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/CTestCustom.cmake)

SET(libengsas_SOURCE_DIR ${CMAKE_SOURCE_DIR}/src/lib/core)
SET(libengsas_BINARY_DIR ${CMAKE_BINARY_DIR}/src/lib/core)
SET(libengsas_testing_SOURCE_DIR ${CMAKE_SOURCE_DIR}/src/lib/testing)
SET(libengsas_testing_BINARY_DIR ${CMAKE_BINARY_DIR}/src/lib/testing)
IF(WITH_CHARTS)
	SET(libengsas_charts_SOURCE_DIR ${CMAKE_SOURCE_DIR}/src/lib/charts)
	SET(libengsas_charts_BINARY_DIR ${CMAKE_BINARY_DIR}/src/lib/charts)
ENDIF(WITH_CHARTS)
ADD_SUBDIRECTORY(src)
ADD_SUBDIRECTORY(doc)
ADD_SUBDIRECTORY(examples)

# printing chosen configuration
MESSAGE("######################################################")
MESSAGE("")
MESSAGE("CONFIGURATION")
MESSAGE("")
MESSAGE("CMAKE_SHARED_LINKER_FLAGS: ${CMAKE_SHARED_LINKER_FLAGS}")
MESSAGE("CMAKE_CXX_FLAGS:           ${CMAKE_CXX_FLAGS}")
MESSAGE("CMAKE_INSTALL_PREFIX:      ${CMAKE_INSTALL_PREFIX}")
MESSAGE("")
MESSAGE("OPTIONS:")
MESSAGE("  Name                             Wanted       Used")
MESSAGE("  BUILD_PACKAGE:                   ${BUILD_PACKAGE_WANTED}		${BUILD_PACKAGE}")
MESSAGE("  BUILD_DEBUG:                     ${BUILD_DEBUG_WANTED}		${BUILD_DEBUG}")
MESSAGE("  BUILD_DEV:                       ${BUILD_DEV_WANTED}		${BUILD_DEV}")
MESSAGE("  BUILD_TESTING:                   ${BUILD_TESTING_WANTED}		${BUILD_TESTING}")
MESSAGE("  BINDINGS_KDE:                    ${BINDINGS_KDE_WANTED}		${BINDINGS_KDE}")
MESSAGE("  COMPATIBLE_WITH_NON_KDE:         ${COMPATIBLE_WITH_NON_KDE_WANTED}		${COMPATIBLE_WITH_NON_KDE}")
# MESSAGE("  WITH_HANDBOOK:                   ${WITH_HANDBOOK_WANTED}		${WITH_HANDBOOK}")
MESSAGE("  L10N_ALL:                        ${L10N_ALL_WANTED}		${L10N_ALL}")
MESSAGE("    L10N_DE:                       ${L10N_DE_WANTED}		${L10N_DE}")
MESSAGE("    L10N_EN:                       ${L10N_EN_WANTED}		${L10N_EN}")
MESSAGE("    L10N_FR:                       ${L10N_FR_WANTED}		${L10N_FR}")
MESSAGE("  WITH_FILE_SERVICE_PLUGINS_ALL:   ${WITH_FILE_SERVICE_PLUGINS_ALL_WANTED}		${WITH_FILE_SERVICE_PLUGINS_ALL}")
MESSAGE("    WITH_FILE_SERVICE_FILESYSTEM:  ${WITH_FILE_SERVICE_FILESYSTEM_WANTED}		${WITH_FILE_SERVICE_FILESYSTEM}")
MESSAGE("  WITH_CHARTS:                     ${WITH_CHARTS_WANTED}		${WITH_CHARTS}")
MESSAGE("  WITH_API_DOCS:                   ${WITH_API_DOCS_WANTED}		${WITH_API_DOCS}")
MESSAGE("  WITH_EXAMPLES:                   ${WITH_EXAMPLES_WANTED}		${WITH_EXAMPLES}") 
MESSAGE("")
MESSAGE("######################################################")

IF(NOT BINDINGS_KDE)
	########### Add uninstall target ###############
	CONFIGURE_FILE(
		"${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
		"${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
		IMMEDIATE @ONLY)
	ADD_CUSTOM_TARGET(uninstall
		"${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
ENDIF(NOT BINDINGS_KDE)

SET(CPACK_GENERATOR "NSIS")
SET(CPACK_PACKAGE_NAME "LibEngsas")
SET(CPACK_PACKAGE_VENDOR "EngSaS - Engineering Solutions and Services Langenbach")
SET(CPACK_NSIS_CONTACT "info@engsas.de")
SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "LibEngsas is a library which improves Qt a little bit and encapsulates KDE bindings if possible")
SET(CPACK_PACKAGE_VERSION ${${PROJECT_NAME}_VERSION})
SET(CPACK_PACKAGE_VERSION_MAJOR ${TARGET_MAJOR_VERSION})
SET(CPACK_PACKAGE_VERSION_MINOR ${TARGET_MINOR_VERSION})
SET(CPACK_PACKAGE_VERSION_PATCH ${${PROJECT_NAME}_PATCH_LEVEL})
#SET(CPACK_PACKAGE_INSTALL_DIRECTORY "DeSuTo/${${PROJECT_NAME}_VERSION}")
SET(CPACK_PACKAGE_INSTALL_DIRECTORY "libengsas")
SET(CPACK_NSIS_INSTALLED_ICON_NAME "$INSTDIR/epartexe.exe")


# add all components which should be installable via the package
IF(WIN32)
	SET(external_DLL qtlibs)
ENDIF(WIN32)

SET(CPACK_COMPONENTS_ALL 
	library
	efilesystemplugin
	applicationepartexe
	charts
	headerfiles
	devfinding
	devdesigner
	devtesting
	devapidocs
	${external_DLL}
	examples
)

# License file
SET(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE.txt)

# Pre selected installation profiles
SET(CPACK_ALL_INSTALL_TYPES Typical Full Minimal)
SET(CPACL_INSTALL_TYPE_TYPICAL_DISPLAY_NAME "Typical")
SET(CPACL_INSTALL_TYPE_FULL_DISPLAY_NAME "Full")
SET(CPACL_INSTALL_TYPE_MINIMAL_DISPLAY_NAME "Minimal")

# groups for components
SET(CPACK_COMPONENT_GROUP_BASE_DISPLAY_NAME "LibEngsas")
SET(CPACK_COMPONENT_GROUP_BASE_DESCRIPTION "The LibEngsas core stuff")
SET(CPACK_COMPONENT_GROUP_DEVELOPMENT_DISPLAY_NAME "Development")
SET(CPACK_COMPONENT_GROUP_DEVELOPMENT_DESCRIPTION "All needed stuff to develop with LibEngsas")
SET(CPACK_COMPONENT_GROUP_FILESERVICEPLUGINS_DISPLAY_NAME "Fileservice Plugins")
SET(CPACK_COMPONENT_GROUP_FILESERVICEPLUGINS_DESCRIPTION "This components provides services to handle files")
SET(CPACK_COMPONENT_GROUP_3RDPARTYLIBS_DISPLAY_NAME "3rd Party Libraries")
SET(CPACK_COMPONENT_GROUP_3RDPARTYLIBS_DESCRIPTION "3rd Party libraries which are needed to run Meganizer and or modules. They are only needed if they are not already exist in PATH")
# SET(CPACK_COMPONENT_GROUP_DOC_DISPLAY_NAME "Documentations")
# SET(CPACK_COMPONENT_GROUP_DOC_DESCRIPTION "Contains all types of available documentations")

# the scheme of the variable names are: CPACK_COMPNONENT_%COMPONENTNAMEINUPPERCASE%_DISPLAY_NAME
# where %COMPONENTNAMEINUPPERCASE% must be replaced by the upper cased name of the component
# see below for example
SET(CPACK_COMPONENT_QTLIBS_DISPLAY_NAME "QT")
SET(CPACK_COMPONENT_QTLIBS_DESCRIPTION 
   "Libraries which are needed, but not belonging to this project. They must not be installed, if they are already installed at path")
SET(CPACK_COMPONENT_QTLIBS_GROUP "3rdPartyLibs")
SET(CPACK_COMPONENT_QTLIBS_INSTALL_TYPES Typical Full)

SET(CPACK_COMPONENT_LIBRARY_DISPLAY_NAME "LibEngsas Library")
SET(CPACK_COMPONENT_LIBRARY_DESCRIPTION "The library itself")
SET(CPACK_COMPONENT_LIBRARY_GROUP "Base") 
SET(CPACK_COMPONENT_LIBRARY_INSTALL_TYPES Typical Full Minimal)

SET(CPACK_COMPONENT_APPLICATIONEPARTEXE_DISPLAY_NAME "EPartExe")
SET(CPACK_COMPONENT_APPLICATIONEPARTEXE_DESCRIPTION "The executable to launch EParts")
SET(CPACK_COMPONENT_APPLICATIONEPARTEXE_GROUP "Base") 
SET(CPACK_COMPONENT_APPLICATIONEPARTEXE_INSTALL_TYPES Typical Full)

##########################
#
# EFileServicePLugins - Group "Fileservice Plugins"
#
##########################
IF(WITH_FILE_SERVICE_FILESYSTEM)
  SET(CPACK_COMPONENT_EFILESYSTEMPLUGIN_DISPLAY_NAME "Filesystem plugin")
  SET(CPACK_COMPONENT_EFILESYSTEMPLUGIN_DESCRIPTION "Module to handle files on local filesystems")
  SET(CPACK_COMPONENT_EFILESYSTEMPLUGIN_GROUP "Fileservice Plugins")
  SET(CPACK_COMPONENT_EFILESYSTEMPLUGIN_INSTALL_TYPES Typical Full)
	SET(CPACK_COMPONENT_EFILESYSTEMPLUGIN_DEPENDS library)
ENDIF(WITH_FILE_SERVICE_FILESYSTEM)

##########################
#
# libengsas-charts
#
##########################
SET(CPACK_COMPONENT_CHARTS_DISPLAY_NAME "LibEngsas Charts Library")
SET(CPACK_COMPONENT_CHARTS_DESCRIPTION "Library module to display charts")
SET(CPACK_COMPONENT_CHARTS_GROUP "Base")
SET(CPACK_COMPONENT_CHARTS_INSTALL_TYPES Typical Full Minimal)
SET(CPACK_COMPONENT_CHARTS_DEPENDS library)

##########################
#
# Development - Group "Development"
#
##########################
IF(BUILD_DEV)
	SET(CPACK_COMPONENT_DEVTESTING_DISPLAY_NAME "LibEngsas testing library")
	SET(CPACK_COMPONENT_DEVTESTING_DESCRIPTION
		 "Library to build tests easier")
	SET(CPACK_COMPONENT_DEVTESTING_GROUP "Development")
	SET(CPACK_COMPONENT_DEVTESTING_INSTALL_TYPES Full)
	SET(CPACK_COMPONENT_DEVTESTING_DEPENEDS library)

	SET(CPACK_COMPONENT_DEVDESIGNER_DISPLAY_NAME "LibEngsas Designer Plugins")
	SET(CPACK_COMPONENT_DEVDESIGNER_DESCRIPTION 
     "QtDesigner Plugins for Widgets provided by LibEngsas")
	SET(CPACK_COMPONENT_DEVDESIGNER_GROUP "Development")
	SET(CPACK_COMPONENT_DEVDESIGNER_INSTALL_TYPES Full)
	SET(CPACK_COMPONENT_DEVDESIGNER_DEPENDS library)

	SET(CPACK_COMPONENT_HEADERFILES_DISPLAY_NAME "Header files of LibEngsas")
	SET(CPACK_COMPONENT_HEADERFILES_DESCRIPTION
     "Contains header files to develop with LibEngsas and it's components")
	SET(CPACK_COMPONENT_HEADERFILES_GROUP "Development")
	SET(CPACK_COMPONENT_HEADERFILES_INSTALL_TYPES Full)
	SET(CPACK_COMPONENT_HEADERFILES_DEPENEDS library)
	
	SET(CPACK_COMPONENT_DEVFINDING_DISPLAY_NAME "Files to find LibEngsas")
	SET(CPACK_COMPONENT_DEVFINDING_DESCRIPTION 
     "Files to find LibEngsas with CMake and pkgconfig")
	SET(CPACK_COMPONENT_DEVFINDING_GROUP "Development")
	SET(CPACK_COMPONENT_DEVFINDING_INSTALL_TYPES Full)
	SET(CPACK_COMPONENT_DEVFINDING_DEPENEDS library)
	
	SET(CPACK_COMPONENT_DEVAPIDOCS_DISPLAY_NAME "API documentation of LibEngsas")
	SET(CPACK_COMPONENT_DEVAPIDOCS_DESCRIPTION 
     "The API documentation of LibEngsas and all packaged stuff")
	SET(CPACK_COMPONENT_DEVAPIDOCS_GROUP "Development")
	SET(CPACK_COMPONENT_DEVAPIDOCS_INSTALL_TYPES Full)
  
	SET(CPACK_COMPONENT_EXAMPLES_DISPLAY_NAME "Examples using LibEngsas") 
	SET(CPACK_COMPONENT_EXAMPLES_DESCRIPTION "Examples using LibEngsas") 
	SET(CPACK_COMPONENT_EXAMPLES_GROUP "Development") 
	SET(CPACK_COMPONENT_EXAMPLES_INSTALL_TYPES Full)
ENDIF(BUILD_DEV)

# used by NSIS to create startmenu links to the executables
# this entrys are only useful if a bin folder is used, otherwise use the empty EXECUTABLES
# and fill out the NSIS_MENU_LINKS
#SET(CPACK_PACKAGE_EXECUTABLES ${CPACK_PACKAGE_EXECUTABLES} "desuto" "DeSuTo")
#SET(CPACK_PACKAGE_EXECUTABLES ${CPACK_PACKAGE_EXECUTABLES} "desutodaemon" "DeSuToDaemon")
SET(CPACK_PACKAGE_EXECUTABLES "" "")

IF(WITH_API_DOCS)
	SET(CPACK_NSIS_MENU_LINKS "${apidocs_DIR}/index.html" "API Documentation")
ENDIF(WITH_API_DOCS)
	
# This must always be last!
INCLUDE(CPack)