######################
#
#    Copyright (C) 2012 - 2013 EngSaS - Engineering Solutions and Services Langenbach. All rights reserved.
#
#    This library is free software; you can redistribute it and/or
#    modify it under the terms of the GNU Lesser General Public
#    License as published by the Free Software Foundation; either
#    version 2.1 of the License, or (at your option) any later version.
#
#    This library is distributed in the hope that it will be useful,
#    but WITHOUT ANY WARRANTY; without even the implied warranty of
#    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
#    Lesser General Public License for more details.
#
#    You should have received a copy of the GNU Lesser General Public
#    License along with this library; if not, write to the Free Software
#    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
#    MA 02110-1301  USA.
#
######################

IF(L10N_DE)
	SET(libengsas_charts_TS ${libengsas_charts_TS} lang/libengsas-charts_de.ts)
ENDIF(L10N_DE)
IF(L10N_EN)
	SET(libengsas_charts_TS ${libengsas_charts_TS} lang/libengsas-charts_en.ts)
ENDIF(L10N_EN)
IF(L10N_FR)
	SET(libengsas_charts_TS ${libengsas_charts_TS} lang/libengsas-charts_fr.ts)
ENDIF(L10N_FR)

SET(libengsas_charts_CPP
	echartbase.cpp
	echartmarkersconfig.cpp
	echartmarkers.cpp
	echartvalues.cpp
	echartline.cpp
	echartpie.cpp
)
IF(WITH_QML)
	SET(QT_USE_QTDECLARATIVE TRUE)
	SET(libengsas_charts_CPP
		${libengsas_charts_CPP}
		echartqmlextension.cpp
		echartbaseqml.cpp
		echartpieqml.cpp
	)
	SET(QML_MODULE_NAME "engsas-charts")
	IF(WIN32)
		SET(QML_MODULE_NAME "libengsas-charts")
	ENDIF(WIN32)
	CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/qmldir.in ${CMAKE_CURRENT_BINARY_DIR}/qmldir)
ENDIF(WITH_QML)

INCLUDE_DIRECTORIES(
	${CMAKE_CURRENT_BINARY_DIR}
	${CMAKE_CURRENT_SOURCE_DIR}
	${CMAKE_CURRENT_BINARY_DIR}/private
	${CMAKE_CURRENT_SOURCE_DIR}/private
	${libengsas_SOURCE_DIR}
	${libengsas_BINARY_DIR}
)
IF(BINDINGS_QT4)
	INCLUDE_DIRECTORIES(${INCLUDE_DIRECTORIES} ${QT_INCLUDES})
	INCLUDE(${QT_USE_FILE})
ENDIF(BINDINGS_QT4)
ADD_DEFINITIONS(-DE_BUILD_CHARTS_LIB)

IF(BINDINGS_QT4)
	QT4_ADD_TRANSLATION(libengsas_charts_TRANS ${libengsas_charts_TS})
ENDIF(BINDINGS_QT4)
IF(BINDINGS_QT5)
	QT5_ADD_TRANSLATION(libengsas_charts_TRANS ${libengsas_charts_TS})
ENDIF(BINDINGS_QT5)

ADD_LIBRARY(libengsas_charts SHARED
	${libengsas_charts_CPP}
	${libengsas_charts_TRANS}
)

TARGET_LINK_LIBRARIES(libengsas_charts
	${QT_LIBRARIES}
	libengsas
)

IF(BINDINGS_QT5)
	qt5_use_modules(libengsas_charts Core Widgets)
	SET(CMAKE_AUTOMOC ON)
    IF(WITH_QML)
        qt5_use_modules(libengsas_charts Qml Quick)
    ENDIF(WITH_QML)
ENDIF(BINDINGS_QT5)

INSTALL(
	FILES ${libengsas_charts_TRANS}
	DESTINATION ${qm_DIR}
	COMPONENT charts
)

SET_TARGET_PROPERTIES(libengsas_charts PROPERTIES
	OUTPUT_NAME "engsas-charts"
	VERSION ${TARGET_VERSION_MAJOR}.${TARGET_VERSION_MINOR}.${${PROJECT_NAME}_PATCH_LEVEL}
	SOVERSION ${TARGET_VERSION_MAJOR})
IF(WIN32)
	INSTALL(TARGETS libengsas_charts 
		RUNTIME DESTINATION ${LIB_INSTALL_DIR} 
		COMPONENT charts 
	)
	IF(MSVC)
		INSTALL(FILES ${LIBRARY_OUTPUT_PATH}/engsas-charts.lib DESTINATION ${LIB_INSTALL_DIR} COMPONENT charts)
	ENDIF(MSVC)
ELSE(WIN32)
	INSTALL(TARGETS libengsas_charts
		LIBRARY DESTINATION ${LIB_INSTALL_DIR}
		ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
		COMPONENT charts
	)
ENDIF(WIN32)

IF(BUILD_DEV)
	FILE(GLOB header "${CMAKE_CURRENT_SOURCE_DIR}/*.h")
	INSTALL(
		FILES ${header}
		DESTINATION ${include_DIR}/charts
		COMPONENT headerfiles
	)

	# CMake overrides ${var} during configuration, therefore we insert it with cmake
	SET(prefix ${CMAKE_INSTALL_PREFIX})
	SET(exec_prefix "\${prefix}")
	SET(libdir "\${exec_prefix}/lib")
	SET(includedir "\${prefix}/include/engsas")
	SET(lib_flag "\${libdir}")
	SET(include_flag "\${includedir}")
	SET(LIBNAME engsas-charts)
	SET(REQUIRES "QtCore >= 4, QtTest >= 4")
	CONFIGURE_FILE(
		${CMAKE_CURRENT_SOURCE_DIR}/libengsas-charts.pc.in
		${CMAKE_CURRENT_BINARY_DIR}/libengsas-charts.pc
	)
	# Install pkgconfig file
	INSTALL(
		FILES ${CMAKE_CURRENT_BINARY_DIR}/libengsas-charts.pc
		DESTINATION ${pkgconfig_DIR}
		COMPONENT devfinding
	)

	IF(WITH_QML)
		INSTALL(
			FILES ${CMAKE_CURRENT_BINARY_DIR}/qmldir
			DESTINATION "${qml_DIR}/charts"
			COMPONENT devqml
		)
	ENDIF(WITH_QML)
ENDIF(BUILD_DEV)