######################
#
#    Copyright (C) 2011 - 2012 EngSaS - Engineering Solutions and Services Langenbach. All rights reserved.
#
#    This library is free software; you can redistribute it and/or
#    modify it under the terms of the GNU Lesser General Public
#    License as published by the Free Software Foundation; either
#    version 2.1 of the License, or (at your option) any later version.
#
#    This library is distributed in the hope that it will be useful,
#    but WITHOUT ANY WARRANTY; without even the implied warranty of
#    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
#    Lesser General Public License for more details.
#
#    You should have received a copy of the GNU Lesser General Public
#    License along with this library; if not, write to the Free Software
#    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
#    MA 02110-1301  USA.
#
######################

IF(BINDINGS_QT4)
	SET(QT_USE_QTTEST TRUE)
	SET(QT_USE_QTDESIGNER TRUE)
ENDIF(BINDINGS_QT4)

SET(libengsas_testing_CPP
	eclosemodalwidgetthread.cpp
	eclosemodalwidgetevent.cpp
	private/ecloser.cpp
	modeltest.cpp
	testpluginforemodulelistwidgetitem.cpp
	testdesignerplugins.cpp
	testeparts.cpp
)
IF(WITH_QML)
	SET(QT_USE_QTDECLARATIVE TRUE)
	SET(libengsas_testing_CPP ${libengsas_testing_CPP}
		eqmlextensionplugintest.cpp
	)
ENDIF(WITH_QML)

INCLUDE_DIRECTORIES(
	${CMAKE_CURRENT_BINARY_DIR}
	${CMAKE_CURRENT_SOURCE_DIR}
	${libengsas_SOURCE_DIR}
	${libengsas_BINARY_DIR}
	${CMAKE_CURRENT_BINARY_DIR}/private
	${CMAKE_CURRENT_SOURCE_DIR}/private
)
IF(BINDINGS_QT4)
	INCLUDE_DIRECTORIES(${INCLUDE_DIRECTORIES} ${QT_INCLUDES})
	INCLUDE(${QT_USE_FILE})
ENDIF(BINDINGS_QT4)
ADD_DEFINITIONS(-DE_BUILD_TESTING_LIB)

ADD_LIBRARY(libengsas_testing SHARED
	${libengsas_testing_CPP}
)

TARGET_LINK_LIBRARIES(libengsas_testing
	${QT_LIBRARIES}
	libengsas
)

IF(BINDINGS_QT5)
	qt5_use_modules(libengsas_testing Core Widgets Test Designer)
	SET(CMAKE_AUTOMOC ON)
    IF(WITH_QML)
        qt5_use_modules(libengsas_testing Qml)
    ENDIF(WITH_QML)
ENDIF(BINDINGS_QT5)

SET_TARGET_PROPERTIES(libengsas_testing PROPERTIES
	OUTPUT_NAME "engsas-testing"
	VERSION ${TARGET_VERSION_MAJOR}.${TARGET_VERSION_MINOR}.${${PROJECT_NAME}_PATCH_LEVEL}
	SOVERSION ${TARGET_VERSION_MAJOR})
IF(BUILD_DEV)
	IF(WIN32)
		INSTALL(TARGETS libengsas_testing
			RUNTIME DESTINATION ${LIB_INSTALL_DIR} 
			COMPONENT devtesting
		)
	ELSE(WIN32)
		INSTALL(TARGETS libengsas_testing
			LIBRARY DESTINATION ${LIB_INSTALL_DIR}
			ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
			COMPONENT devtesting
		)
	ENDIF(WIN32)
	IF(MSVC)
		INSTALL(FILES ${LIBRARY_OUTPUT_PATH}/engsas-testing.lib DESTINATION ${LIB_INSTALL_DIR} COMPONENT devtesting)
	ENDIF(MSVC)
ENDIF(BUILD_DEV)

IF(BUILD_DEV)
	IF(PACK_WIN32_STUFF)
		# Qt itself
		FIND_FILE(pack_qttest QtTest4.dll PATHS ${PACK_HINTS} NO_DEFAULT_PATH)
		
		INSTALL(
			FILES 
				${pack_qttest}
			DESTINATION ${bin_DIR}
			COMPONENT qtlibs
		)
	ENDIF()

	FILE(GLOB header "${CMAKE_CURRENT_SOURCE_DIR}/*.h")
	INSTALL(
		FILES ${header}
		DESTINATION ${include_DIR}/testing
		COMPONENT headerfiles
	)

	# CMake overrides ${var} during configuration, therefore we insert it with cmake
	SET(prefix ${CMAKE_INSTALL_PREFIX})
	SET(exec_prefix "\${prefix}")
	SET(libdir "\${exec_prefix}/lib")
	SET(includedir "\${prefix}/include/engsas")
	SET(lib_flag "\${libdir}")
	SET(include_flag "\${includedir}")
	SET(LIBNAME engsas-testing)
	SET(REQUIRES "QtCore >= 4, QtTest >= 4")
	CONFIGURE_FILE(
		${CMAKE_CURRENT_SOURCE_DIR}/libengsas-testing.pc.in
		${CMAKE_CURRENT_BINARY_DIR}/libengsas-testing.pc
	)
	# Install pkgconfig file
	INSTALL(
		FILES ${CMAKE_CURRENT_BINARY_DIR}/libengsas-testing.pc
		DESTINATION ${pkgconfig_DIR}
		COMPONENT devfinding
	)
ENDIF(BUILD_DEV)